import Property
import HostName
import qualified Property.Apt as Apt
import qualified Property.Ssh as Ssh
import qualified Property.User as User
import qualified Property.Hostname as Hostname
import qualified Property.Reboot as Reboot
import qualified Property.Tor as Tor
import qualified Property.GitHome as GitHome

main :: IO ()
main = ensureProperties . getProperties =<< getHostName

{- This is where the system's HostName, either as returned by uname
 - or one specified on the command line is converted into a list of
 - Properties for that system. -}
getProperties :: HostName -> [Property]
getProperties "clam.kitenet.net" = concat
	[ cleanCloudAtCost
	, standardSystem Apt.Unstable
	-- Clam is a tor bridge.
	, Tor.isBridge
	-- This is not an important system so I don't want to need to 
	-- manually upgrade it.
	, Apt.unattendedUpgrades True
	-- Should come last as it reboots.
	, Apt.installed ["systemd-sysv"] `onChange` Reboot.now
	]
-- add more hosts here...
--getProperties "foo" =
getProperties h = error $ "Unknown host: " ++ h ++ " (perhaps you should specify the real hostname on the command line?)"

-- Clean up the system as installed by cloudatcost.com
cleanCloudAtCost :: [Property]
cleanCloudAtCost = 
	[ User.nuked "user"
	, Apt.removed ["exim4"] `onChange` Apt.autoRemove
	, Hostname.set "clam.kitenet.net"
	, Ssh.uniqueHostKeys
	]

-- This is my standard system setup
standardSystem :: Suite -> [Property]
standardSystem suite = 
	[ Apt.stdSourcesList suite `onChange` Apt.upgrade
	, Apt.installed ["etckeeper"]
	, Apt.installed ["ssh"]
	, GitHome.installedFor "root"
	-- Harden the system, but only once root's authorized_keys
	-- is safely in place.
	, check (Ssh.hasAuthorizedKeys "root") $
		Ssh.passwordAuthentication False
	, check (Ssh.hasAuthorizedKeys "root") $
		User.lockedPassword "root"
	, Apt.installed ["vim"]
	, User.nonsystem "joey"
	, Apt.installed ["sudo"]
	-- nopasswd because no password is set up for joey.
	, lineInFile "/etc/sudoers" "joey ALL=(ALL:ALL) NOPASSWD:ALL"
	, GitHome.installedFor "joey"
	]