107 lines
2.6 KiB
Haskell
107 lines
2.6 KiB
Haskell
module Propellor.Types where
|
|
|
|
import Data.Monoid
|
|
import System.Console.ANSI
|
|
|
|
type HostName = String
|
|
type UserName = String
|
|
|
|
data Property = Property
|
|
{ propertyDesc :: Desc
|
|
-- | must be idempotent; may run repeatedly
|
|
, propertySatisfy :: IO Result
|
|
}
|
|
|
|
data RevertableProperty = RevertableProperty Property Property
|
|
|
|
class IsProp p where
|
|
-- | Sets description.
|
|
describe :: p -> Desc -> p
|
|
toProp :: p -> Property
|
|
-- | Indicates that the first property can only be satisfied
|
|
-- once the second one is.
|
|
requires :: p -> Property -> p
|
|
|
|
instance IsProp Property where
|
|
describe p d = p { propertyDesc = d }
|
|
toProp p = p
|
|
x `requires` y = Property (propertyDesc x) $ do
|
|
r <- propertySatisfy y
|
|
case r of
|
|
FailedChange -> return FailedChange
|
|
_ -> propertySatisfy x
|
|
|
|
instance IsProp RevertableProperty where
|
|
-- | Sets the description of both sides.
|
|
describe (RevertableProperty p1 p2) d =
|
|
RevertableProperty (describe p1 d) (describe p2 ("not " ++ d))
|
|
toProp (RevertableProperty p1 _) = p1
|
|
(RevertableProperty p1 p2) `requires` y =
|
|
RevertableProperty (p1 `requires` y) p2
|
|
|
|
type Desc = String
|
|
|
|
data Result = NoChange | MadeChange | FailedChange
|
|
deriving (Read, Show, Eq)
|
|
|
|
instance Monoid Result where
|
|
mempty = NoChange
|
|
|
|
mappend FailedChange _ = FailedChange
|
|
mappend _ FailedChange = FailedChange
|
|
mappend MadeChange _ = MadeChange
|
|
mappend _ MadeChange = MadeChange
|
|
mappend NoChange NoChange = NoChange
|
|
|
|
-- | High level descritption of a operating system.
|
|
data System = System Distribution Architecture
|
|
deriving (Show)
|
|
|
|
data Distribution
|
|
= Debian DebianSuite
|
|
| Ubuntu Release
|
|
deriving (Show)
|
|
|
|
data DebianSuite = Experimental | Unstable | Testing | Stable | DebianRelease Release
|
|
deriving (Show)
|
|
|
|
type Release = String
|
|
|
|
type Architecture = String
|
|
|
|
-- | Results of actions, with color.
|
|
class ActionResult a where
|
|
getActionResult :: a -> (String, ColorIntensity, Color)
|
|
|
|
instance ActionResult Bool where
|
|
getActionResult False = ("failed", Vivid, Red)
|
|
getActionResult True = ("done", Dull, Green)
|
|
|
|
instance ActionResult Result where
|
|
getActionResult NoChange = ("ok", Dull, Green)
|
|
getActionResult MadeChange = ("done", Vivid, Green)
|
|
getActionResult FailedChange = ("failed", Vivid, Red)
|
|
|
|
data CmdLine
|
|
= Run HostName
|
|
| Spin HostName
|
|
| Boot HostName
|
|
| Set HostName PrivDataField
|
|
| AddKey String
|
|
| Continue CmdLine
|
|
| Chain HostName
|
|
| Docker HostName
|
|
deriving (Read, Show, Eq)
|
|
|
|
-- | Note that removing or changing field names will break the
|
|
-- serialized privdata files, so don't do that!
|
|
-- It's fine to add new fields.
|
|
data PrivDataField
|
|
= DockerAuthentication
|
|
| SshPrivKey UserName
|
|
| Password UserName
|
|
| PrivFile FilePath
|
|
deriving (Read, Show, Ord, Eq)
|
|
|
|
|